Loja Virtual - A cesta de Compras

A sua Loja Virtual - Criando a cesta de Compras

Após o usuário ser identificado, a cada compra ele é direcionado para sua cesta de compras onde pode ver a posição atual de suas compras.

Para criar uma loja virtual usando ASP .NET acompanhe o curso no link :

ASP .NET - Criando um site completo com carrinho de compras (Curso)

A figura abaixo exibe a janela da cesta de compras. Vejamos a janela gerada pelo arquivo comprar.asp em detalhes:

Figura 1.0 - Cesta de compras - comprar.asp

Após o Nome da Empresa e a indicação de CopyRight , o nome do usuário aparece após o título - Cesta de Compras. A seguir temos uma tabela onde são exibidos os seguintes itens:

A primeira coluna - Excluir Item - Permite que possamos excluir qualquer item da cesta de compras. Para isto basta clicar em Excluir na linha referente ao produto que desejamos excluir. Vamos excluir a primeira linha , referente ao item - Aprenda Rápido - ASP . Veja abaixo o resultado :

figura 2.0 - O resultado da exclusão do primeiro item

Perceba que o o total da cesta foi recalculado.

A segunda Coluna indica o nome do Produto
A terceira coluna indica o preço unitário do Produto
A quarta Coluna indica a quantidade comprada de cada produto. Para alterar uma quantidade basta informar o novo valor da quantidade para o produto desejado e clicar no botão Alterar.Como exemplo vamos alterar a quantidade do primeiro item , o livro - Aprenda Rápido ASP - , para 3 e clicar no botão alterar. Abaixo temos o resultado:

figura 3.0 - Alterando a quantidade de um item

Observe que o sistema recalcula o valor do total do item e o valor total da cesta de compras.

A última coluna exibe o total para cada item . Sendo que temos o cálculo da soma dos totais dos itens indicando o valor total da cesta de compras.

Vamos agora ver o código que esta por trás de todo esse processamento.

O código do arquivo comprar.asp é dado a seguir:

<%@ Language=VBScript %>
<%
Option Explicit

on error resume next

'Declara Variáveis
Dim conntemp
Dim rsPedidos
Dim totalgeral
Dim PedidoID
Dim SQL
Dim urlimagem
Dim quantidade
Dim campo

'Se o cliente ainda nao foi identificado chama a página de identificacao
If ( Session("ClienteID") = 0 ) Then
 Response.Redirect "Identifica.asp?Tipo=NOVO"
End If

'--------------------------------------
'Abre conexão com o banco de dados
'--------------------------------------
Sub Abre_Conexao
Set conntemp = Server.CreateObject("ADODB.Connection")
conntemp.Open Application("Conecta_bd")
End Sub

'--------------------------------------
'Fecha conexão com o banco de dados
'--------------------------------------
Sub Fecha_Conexao
 conntemp.Close
 Set conntemp = Nothing
End Sub

'---------------------------------------------
'Processa alteracao de quantidades do pedido
'---------------------------------------------
Sub Processa_Alteracao
Conntemp.Execute("Delete * from Itens_Pedidos where PedidoID = " & Session("PedidoID"))

for each campo in Request.form
if Request.Form(campo)<>"0" then
 Conntemp.Execute("INSERT INTO Itens_Pedidos (PedidoID,ProdutoID,Quantidade) values (" & Session("PedidoID") & _ "," & campo & "," & Request.Form(campo) & ")")
end if
next
End Sub
%>

<html>

<head>
<meta http-equiv="Content-Type"
content="text/html; charset=iso-8859-1">
<meta name="GENERATOR" content="Microsoft FrontPage 4.0">
<title>A sua Loja de Software Virtual</title>
</head>

<body bgcolor="#FFFFFF" link="#FFFFFF" vlink="#FFFFFF" alink="#FFFFFF">

<%
Abre_Conexao

if Request.Form <> "" then
 Processa_Alteracao
End if

'pega os itens da cesta de compras
sql= "SELECT pedidos.pedidoId, itens_pedidos.itemID, itens_pedidos.ProdutoID, produtos.nome, produtos.valor, itens_pedidos.quantidade, produtos.urlimagem"
sql= sql & " FROM (itens_pedidos INNER JOIN pedidos ON itens_pedidos.PedidoID = pedidos.pedidoId) INNER JOIN produtos ON itens_pedidos.ProdutoID = produtos.ProdutoID"
sql= sql & " WHERE pedidos.fechado=False"
sql= sql & " AND pedidos.clienteId=" & clng(session("ClienteID"))

'Abre o Recordset de Pedidos do Cliente
Set rsPedidos = conntemp.Execute (SQL) ', , adCmdText)

'identifica o pedido
if ( rsPedidos.EOF ) then
 PedidoID = 0
Else
 PedidoID = rsPedidos("PedidoID")
 session("PedidoId")=clng(rsPedidos("PedidoID"))
End If
%>


<table border="0" width="698">
<tr>
<TD bgcolor="#FFFFFF" width="689">
JcmSoft
- A sua Loja Virtual
</TD>
</tr>
<tr>
<TD align=middle bgColor=#008080 width="689">
Copyright JcmSoft. Todos os direitos reservados
</TD>
</tr>
<tr>
<td width="689">Cesta
de Compras - <%=Session("ClienteNome")%>
<%
if rsPedidos.EOF then
 response.write(" ==> Não existe nenhum item em sua cesta de compras !")%>
<table border="0" width="100%">
<tr>
<td width="100%"><hr></td>
</tr>
<tr>
<td width="100%"><a href="http://macorati/loja/index.htm"><img border="0" src="IMAGENS/cont_cpra.gif">Con</a></td>
</tr>
</table>
<%
else
%>
</td>
</tr>
</table>
<table border="0" width="100%" bgcolor="#008080" cellspacing="0" cellpadding="0">
<tr>
<td width="100%" bgcolor="#FFFFFF" colspan="2">
<form method="POST" action="comprar.asp">
<table border="1" width="692" cellspacing="1">
<tr>
<td width="82">

Excluir Item

</td>
<td width="357">
 Nome
do Produto</td>
<td width="87">
Preço Unitário</td>
<td width="67">
Qtde</td>
<td width="81">
Total</td>
</tr>
<tr>
<%
totalgeral=0.0
with rspedidos

do while not .EOF
%>

<td width="82" bgcolor="#008080">
<a href="compre.asp?operacao=excluir&ItemID=<%=.Fields("itemID")%>&PedidoID=_

<%=.Fields("PedidoID")%>"Excluir</a>
</td>
<td width="357"><%=.fields("nome")%> </td>
<td width="87">
<%=formatCurrency(.fields("valor"))%> </td>
<td width="67">
<input type="text" name="<%=.fields("ProdutoID")%>" size="3" maxlength="3" value="<%=.fields("quantidade")%>" </td>
<td width="81">
<%=formatnumber((.fields("quantidade")* .fields("valor")),2)%> </td>
</tr>
<tr>
<% totalgeral = totalgeral + .Fields("quantidade")* .Fields("valor")
.movenext
loop
end with
%>

<td width="598" colspan="4">

 
</td>
<td width="81">
<%=formatcurrency(totalgeral)%> </td>
</tr>
<tr>
<td width="684" colspan="5">
<input type="submit" value="Alterar" name="submit1">  (Para alterar a quantidade , informe o novo valor e clique no Link Alterar. )
</td>
</tr>
</table>
</form>
</td>
</tr>
<tr>
<td width="50%" bgcolor="#FFFFFF">
<a href="http://macorati/loja/index.htm"><img border="0" src="IMAGENS/cont_cpra.gif">Con</a></td>
<td width="50%" bgcolor="#FFFFFF">
<a href="http://macorati/loja/destino.asp"><img border="0" src="IMAGENS/enc_cpra.gif"></a></td>
</tr>
</table>
</body>
</html>
<%
end if
'Fecha o Recordset de Pedidos e conexao com o bd
Session("TotalGeral") = totalgeral

rsPedidos.Close
Set rsPedidos = Nothing
Fecha_Conexao
%>

Iniciamos definindo a linguagem de script padrão (<%@ Language=VBScript %>)
Usamos a declaração ( Option Explicit ) para obrigar a declaração das variáveis
Ativamos o tratamento de erros ( On error Resume Next )
A seguir declaramos as variáveis usadas

'Declara Variáveis
Dim conntemp
Dim rsPedidos
Dim totalgeral
Dim PedidoID
Dim SQL
Dim urlimagem
Dim quantidade
Dim campo

Verificamos se o cliente já foi identificado (Session("ClienteID") = 0 ) . Se o cliente não foi identificado a variável de sessão ClienteID terá o valor zero. Neste caso redirecionamos o processamento para a página Identifica.asp ( Response.Redirect "Identifica.asp?Tipo=NOVO") com o parâmetro tipo=NOVO.

'Se o cliente ainda nao foi identificado chama a página de identificacao
If ( Session("ClienteID") = 0 ) Then
Response.Redirect "Identifica.asp?Tipo=NOVO"
End If

Definimos as procedures Abre_Conexão e Fecha_Conexão.

'--------------------------------------
'Abre conexão com o banco de dados
'--------------------------------------
Sub Abre_Conexao
Set conntemp = Server.CreateObject("ADODB.Connection")
conntemp.Open Application("Conecta_bd")
End Sub

'--------------------------------------
'Fecha conexão com o banco de dados
'--------------------------------------
Sub Fecha_Conexao
conntemp.Close
Set conntemp = Nothing
End Sub

Definimos a procedure que fará a alteração da quantidade nos itens dos pedidos

'---------------------------------------------
'Processa alteracao de quantidades do pedido
'---------------------------------------------
Sub Processa_Alteracao
Conntemp.Execute("Delete * from Itens_Pedidos where PedidoID = " & Session("PedidoID"))
for each campo in Request.form
if Request.Form(campo)<>"0" then
Conntemp.Execute("INSERT INTO Itens_Pedidos (PedidoID,ProdutoID,Quantidade) values (" & Session("PedidoID") & "," & campo & "," & Request.Form(campo) & ")")
end if
next
End Sub

Observe que primeiro excluímos todos os pedidos para os pedidos definidos na sessão :

Conntemp.Execute("Delete * from Itens_Pedidos where PedidoID = " & Session("PedidoID"))

e a seguir incluímos os novos valores para cada campo do formulário:

Conntemp.Execute("INSERT INTO Itens_Pedidos (PedidoID,ProdutoID,Quantidade) values (" & Session("PedidoID") & "," & campo & "," & Request.Form(campo) & ")")

Abrimos uma conexão ( Abre_Conexao ) e verificamos se houve um pedido para alterar a quantidade de itens dos pedidos ( if Request.Form <> "" then Processa_Alteracao End if )

A seguir montamos a string SQL onde selecionarmos os itens dos pedidos para o Cliente idenficado na sessão:

'pega os itens da cesta de compras
sql= "SELECT pedidos.pedidoId, itens_pedidos.itemID, itens_pedidos.ProdutoID, produtos.nome, produtos.valor, itens_pedidos.quantidade, produtos.urlimagem"
sql= sql & " FROM (itens_pedidos INNER JOIN pedidos ON itens_pedidos.PedidoID = pedidos.pedidoId) INNER JOIN produtos ON itens_pedidos.ProdutoID = produtos.ProdutoID"
sql= sql & " WHERE pedidos.fechado=False"
sql= sql & " AND pedidos.clienteId=" & clng(session("ClienteID"))

Abrimos o Recordset do pedido para o cliente usando a string SQL montada anteriormente

'Abre o Recordset de Pedidos do Cliente
Set rsPedidos = conntemp.Execute (SQL) ', , adCmdText)

Fazemos a identificação do Pedido : Se não há nenhum pedido ainda atribuímos o valor zero, caso contrário definimos o código do pedido para a sessão atual. A seguir incluímos o arquivo ADOVBS.INC com as constantes ADO.

identifica o pedido
if ( rsPedidos.EOF ) then
 PedidoID = 0
Else
 PedidoID = rsPedidos("PedidoID")
 session("PedidoId")=clng(rsPedidos("PedidoID"))
End If
%>

Exibimos o nome do cliente que esta efetuando as compras:

<td width="689">Cesta de Compras - <%=Session("ClienteNome")%>

Se não existir nenhum item na cesta do exibe mensagem :

<% if rsPedidos.EOF then response.write(" ==> Não existe nenhum item em sua cesta de compras !")%>

A seguir montamos o formulário exibindo os itens do pedido :

Usamos o método POST , onde a ação executada será acionar o arquivo Comprar.asp
Definimos o cabeçalho identificado o produto , preço , quantidade e total

<form method="POST" action="comprar.asp">
<table border="1" width="692" cellspacing="1">
<tr>
<td width="82">

Excluir Item

</td>
<td width="357">
 Nome
do Produto</td>
<td width="87">
Preço Unitário</td>
<td width="67">
Qtde</td>
<td width="81">
Total</td>
</tr>
<tr>

totalgeral=0.0
with rspedidos

Percorremos o Recordset do pedido( with rspedidos) até o final ( do while not .EOF ) e montamos com os dados do existentes no Recordset a cesta de compras item a item do formulário , para cada coluna. Assim temos:

1-) Primeira Columa : Excluir Item - Ação a ser executada quando o usuário clicar no Link - Excluir:

href="compre.asp?operacao=excluir&ItemID=<%=.Fields("itemID")%>&PedidoID=_

<%=.Fields("PedidoID")%>"

O arquivo compre.asp será acionado com os parâmetros indicando o no. do item (ItemID=<%=.Fields("itemID") e o código do Pedido ( PedidoID=<%=.Fields("PedidoID")%>")

2-) Segunda Coluna: Nome do Produto - Exibe o nome do produto comprado:

3-) Terceira Coluna : Preço Unitário - Exibe o preço unitário do produto:

<%=formatCurrency(.fields("valor"))%> </td>

4-) Quarta Coluna : Quantidade - Exibe a quantidade comprada do produto:

<input type="text" name="<%=.fields("ProdutoID")%>" size="3" maxlength="3" value="<%=.fields("quantidade")%>"

Observe que relacionamos a quantidade ao código do produto para permitir sua identificação.

5-) Quinta Coluna : Total - Exibe o valor total comprado para este produto:

<%=formatnumber((.fields("quantidade")* .fields("valor")),2)%>

Note que obtemos o valor total multiplicando a quantidade pelo valor.

5-) Finalmente acrescentamos o valor do pedido(.Fields("quantidade")* .Fields("valor")) a variável totalgeral e movemos o ponteiro para o próximo registro do recordset(.movenext) . Após percorrer todo o Recordset a variável totalgeral irá conter o valor total da cesta de compras.

<% totalgeral = totalgeral + .Fields("quantidade")* .Fields("valor")
.movenext

do while not .EOF
%>

<td width="82" bgcolor="#008080">
<a href="compre.asp?operacao=excluir&ItemID=<%=.Fields("itemID")%>&PedidoID=_

<%=.Fields("PedidoID")%>"Excluir</a>
</td>
<td width="357"><%=.fields("nome")%> </td>
<td width="87">
<%=formatCurrency(.fields("valor"))%> </td>
<td width="67">
<input type="text" name="<%=.fields("ProdutoID")%>" size="3" maxlength="3" value="<%=.fields("quantidade")%>" </td>
<td width="81">
<%=formatnumber((.fields("quantidade")* .fields("valor")),2)%> </td>
</tr>
<tr>
<% totalgeral = totalgeral + .Fields("quantidade")* .Fields("valor")
.movenext
loop
end with
%>

<td width="598" colspan="4">

 
</td>
<td width="81">
<%=formatcurrency(totalgeral)%> </td>
</tr>
<tr>
<td width="684" colspan="5">
<input type="submit" value="Alterar" name="submit1">  (Para alterar a quantidade , informe o novo valor e clique no Link Alterar. )
</td>
</tr>
</table>
</form>

Para encerrar associamos ao botão Continuar Compras (cont_cpra.gif) o código:

<a href="http://macorati/loja/index.htm"><img border="0" src="IMAGENS/cont_cpra.gif">Con</a>

Quando o botão for acionado o usuário será levado a página inicial ( index.htm )

e ao botão Encerrar Compras(enc_cpra.gif) o código:

<a href="http://macorati/loja/destino.asp"><img border="0" src="IMAGENS/enc_cpra.gif"></a>

que quando acionado irá acionar o arquivo destino.asp que exibirá os dados do destinatário do pedido. Ver abaixo:

figura 4.0 - O formulário gerado pelo arquivo destino.asp

O arquivo destino.asp apenas exibe o nome do destinatário do pedido . Seu código é exibido a seguir:

<%@ Language=VBScript %>
<%
Option Explicit

'Declara Variáveis
Dim conntemp
Dim SQL
Dim rsclientes

'Se o cliente ainda nao foi identificado chama a página de identificacao
If ( Session("ClienteID") = 0 ) Then
Response.Redirect "Identifica.asp?Tipo=NOVO"
End If

'--------------------------------------
'Abre conexão com o banco de dados
'--------------------------------------
Sub Abre_ConexaoBD
Set conntemp = Server.CreateObject("ADODB.Connection")
conntemp.Open Application("Conecta_bd")
End Sub

'--------------------------------------
'Fecha conexão com o banco de dados
'--------------------------------------
Sub Fecha_ConexaoBD
conntemp.Close
Set conntemp = Nothing
End Sub

Abre_ConexaoBD

SQL = "Select * from Clientes Where ClienteID= " & session("ClienteID")
set rsclientes = conntemp.Execute (SQL)

%>
<html>
<head>
<meta http-equiv="Content-Language" content="pt-br">
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
<meta name="GENERATOR" content="Microsoft FrontPage 4.0">
<meta name="ProgId" content="FrontPage.Editor.Document">
<title>Caixa</title>
</head>
<body link="#008080" vlink="#008080" alink="#008080">
<table border="0" width="698">
<tr>
<TD bgcolor="#FFFFFF" width="689">
JcmSoft
- A sua Loja Virtual
</TD>
</tr>
<tr>
<TD align=middle bgColor=#008080 width="689">
Copyright JcmSoft. Todos os direitos reservados
</TD>
</tr>
<tr>
<td width="689">Destinatário</td> </tr>
</table>

<form method="POST" action="caixa.asp" onsubmit="return checa_dados()" name="remessa">
Endereço do Destinatário
(Para alterar informe novos dados e clique no botão - Confirma)

<hr color="#008080" style="margin-top: -20">
<div align="left" style="width: 741; height: 293">
<table BORDER="0" CELLPADDING="0" CELLSPACING="0" height="194" width="741">
<tr>
<td height="26" width="21">
Nome:
</td>
<td height="26" width="708">
<input type="text" name="nome" size="35" value="<%=rsclientes("ClienteNome")%>">
</td>
</tr>
<tr>
<td height="26" width="21">
Endereço:
</td>
<td height="26" width="708">
<input NAME="endereco" TYPE="text" SIZE="35" value="<%=rsclientes("ClienteEndereco")%>">
</td>
</tr>
<tr>
<td height="27" width="21">
Cidade:
</td>
<td height="27" width="708">
<input NAME="cidade" TYPE="text" SIZE="35" value="<%=rsclientes("ClienteCidade")%>" >   
</td>
</tr>
<tr>
<td height="24" width="21">
UF:
</td>
<td height="24" width="708">
<input NAME="estado" TYPE="text" SIZE="2" maxlenght="2" value="<%=rsclientes("ClienteEstado")%>" 

</td>
</tr>
<tr>
<td width="21" height="29">
CEP:
</td>
<td width="704" height="29">
<input NAME="cep" TYPE="text" SIZE="11" value="<%=rsclientes("ClienteCep")%>">
</td>
</tr>
<tr>
<td width="725" height="33" colspan="2">
<hr>
</td>
</tr>
<tr>
<td width="229" height="33">
<input type="submit" value="Confirma" name="confirma">
</td>
<td width="496" height="33">
<a href="http://macorati/loja/comprar.asp"><img border="0" src="IMAGENS/retorna.gif"></a>
</td>
</tr>
</table>
<%
rsclientes.close
set rsclientes=nothing
Fecha_ConexaoBD
%>
</div>
</form>
</body>
</html>

<SCRIPT LANGUAGE="JavaScript">

</SCRIPT>

O arquivo basicamente faz o seguinte ao ser processado:

Abre a conexão e exibe os dados do cliente identificado na sessão gerando o recordset RsClientes

Abre_ConexaoBD

SQL = "Select * from Clientes Where ClienteID= " & session("ClienteID")
set rsclientes = conntemp.Execute (SQL)

O formulário (name=remessa) usado para exibir os dados usa o método POST e a ação executada é acionar o arquivo caixa.asp. Durate a submissão usamos o arquivo de script ( JavaScript ) checa_dados

O formulário é montado com os dados do recordset rsclientes como abaixo:

Nome : <%=rsclientes("ClienteNome")%>
Endereço : <%=rsclientes("ClienteEndereco")%>">
Cidade : <%=rsclientes("ClienteCidade")%>
UF : <%=rsclientes("ClienteEstado")%>
CEP : <%=rsclientes("ClienteCep")%>

O botão Confirma submete o formulário e o envia para o caixa , enquanto que o Link Retorna faz com que a página anterior seja exibida novamente.
Para encerrar fechamos o recordset , liberamos a memória e fechamos a conexão:

rsclientes.close
set rsclientes=nothing
Fecha_ConexaoBD
%>

Parte Anterior Próxima parte

Veja os Destaques e novidades do SUPER DVD Visual Basic (sempre atualizado) : clique e confira !

Quer migrar para o VB .NET ?

Veja mais sistemas completos para a plataforma .NET no Super DVD .NET , confira...
Curso Básico VB .NET - Vídeo Aulas

Quer aprender C# ??

Chegou o Super DVD C# com exclusivo material de suporte e vídeo aulas com curso básico sobre C#.
Curso C# Basico - Video Aulas

Quer aprender os conceitos da Programação Orientada a objetos ?

Curso Fundamentos da Programação Orientada a Objetos com VB .NET

Quer aprender o gerar relatórios com o ReportViewer no VS 2013 ?

Curso - Gerando Relatórios com o ReportViewer no VS 2013 - Vídeo Aulas

Quer aprender a criar aplicações Web Dinâmicas usando a ASP .NET MVC 5 ?

Curso ASP .NET MVC 5 - Vídeo Aulas

Gostou ? Compartilhe no Facebook Compartilhe no Twitter

Referências:

José Carlos Macoratti