Imports System
Imports System.Linq
Imports System.Data.Linq.Mapping

<Table(name:="Categorias")> _
Public Class Categoria
    Private _Id As Integer
    Private _nome As String
    Private _descricao As String

    <Column(IsPrimaryKey:=True, IsDbGenerated:=True)> _
    Public Property CategoriaId() As Integer
        Get
            Return _Id
        End Get

        Set(ByVal value As Integer)
            _Id = value
        End Set
    End Property

    <Column(CanBeNull:=True)> _
    Public Property CategoriaNome() As String
        Get
            Return _nome
        End Get

        Set(ByVal value As String)
            _nome = value
        End Set
    End Property

    <Column(CanBeNull:=True)> _
    Public Property CategoriaDescricao() As String
        Get
            Return _descricao
        End Get

        Set(ByVal value As String)
            _descricao = value
        End Set
    End Property
End Class

O atributo <Table> possui a propriedade Name que podemos usar para especificar o nome exato
da tabela do banco de dados. Se a propriedade Name não for informada o LINQ To SQL  irá assumir
que a tabela do banco de dados possui o mesmo nome da classe.

No nosso exemplo a classe Categoria consiste de 3 propriedades publicas : categoriaid,categorianome
e categoriadescricao. O que torna esta classe especial são os atributos <Table> e <Column>.

O atributo <Table> na classe Categoria indica que a classe representa uma tabela de um SGBD.

A propriedade Name do atributo <Table> especifica o nome da tabela no banco de dados. Se a classe e
tabela tiverem o mesmo nome você não precisa definir a propriedade Name.

Somente as instâncias das classes declaradas como tabelas serão armazenadas no banco de dados.
Instâncias desses tipos de classes são conhecidas como entidades e as classes como classes de entidades.

Para associar a classe com a tabela precisamos definir cada campo ou propriedade que desejamos associar
com a coluna do banco de dados e para isso usamos o atributo Column.

A atributo <Column> especifica que a propriedade relacionada é uma coluna de uma tabela. Este atributo
possui diversas propriedades, a seguir temos as mais importantes:

• Name: O nome da coluna da tabela;
• DbType: O tipo de dados da coluna da tabela;
• IsPrimaryKey:  Indica se a coluna representa a chave primária da tabela;
• IsDbGenerated: Indica se os valores da coluna serão gerados pelo SGBD automaticamente.
  (Ex: colunas do tipo identity)
• CanBeNull: Indica se uma coluna pode receber o valor null;
• Storage: O nome do campo na classe que armazena os dados da coluna;

No nosso exemplo categoriaid é marcada com a propriedades IsPrimaryKey indicando que representa
uma chave primária. 

  <connectionStrings>
    <add name ="ConexaoNorthwind"
         connectionString ="Data Source=.\SQLEXPRESS;AttachDbFilename=C:\dados\NORTHWND.MDF;Integrated Security=True;Connect Timeout=30;User Instance=True"
                 providerName="System.Data.SqlClient" />    
  </connectionStrings>

<%@ Page Title="Home Page" Language="vb" MasterPageFile="~/Site.Master" AutoEventWireup="false"
    CodeBehind="Default.aspx.vb" Inherits="LINQtoSQL_Entidades._Default" %>

<asp:Content ID="HeaderContent" runat="server" ContentPlaceHolderID="HeadContent">
</asp:Content>
<asp:Content ID="BodyContent" runat="server" ContentPlaceHolderID="MainContent">
    <h2>
        <asp:GridView ID="gdvDados" runat="server" Height="265px" Width="622px"> </asp:GridView>
        <asp:Button ID="btnProcurar" runat="server" Text="Procurar" Width="172px" />
        <asp:TextBox ID="txtNome" runat="server" BackColor="#FFFFE6" Width="457px"></asp:TextBox>
    </h2>
</asp:Content>

Imports System.Web.Configuration
Imports System.Data.Linq

Public Class _Default
    Inherits System.Web.UI.Page
    Protected Sub btnProcurar_Click(ByVal sender As Object, ByVal e As EventArgs) Handles btnProcurar.Click

        Dim con As String = WebConfigurationManager.ConnectionStrings("ConexaoNorthwind").ConnectionString
        Dim db As New DataContext(con)
        Dim categoria = db.GetTable(Of Categoria)()

        gdvDados.DataSource = categoria.Where(Function(p) p.CategoriaNome.Contains(txtNome.Text))
        gdvDados.DataBind()
    End Sub
End Class